매크로에서 페이지 나누기로 페이지 아래쪽에 테두리를 그립니다.

개요입니다.

인쇄할 때 제목과 4면 테두리가 용지 프레임으로 사용되는 경우가 있습니다. 그러나 용지가 단일 용지인 경우 테두리를 수동으로 그리기만 하면 되지만 여러 페이지가 되면 테두리가 각 페이지 하단에 표시되지 않습니다. 또한 수동 그리기 지원도 있지만 중간에 행을 추가하거나 제거하는 경우 모든 페이지에 테두리를 그려야 합니다.

이 섹션에서는 매크로를 사용하여 모든 페이지 아래쪽에 테두리를 자동으로 그리는 방법에 대해 설명합니다.

작업 확인 버전입니다.

지원되는 Excel 버전입니다.

• 2010。
• 2007。
• 2003。
• (다른 버전에서 작동하지만 확인되지 않을 수 있습니다.)

Excel 버전을 확인합니다.

• 2010。
• 2007。
• 2003。

콘텐츠입니다.

페이지 수가 1페이지인 경우 행 아래쪽 테두리를 아무 문제 없이 인쇄할 수 있습니다.

그러나 페이지가 여러 개 있는 경우 각 페이지의 아래쪽 줄에는 테두리만 표시되지 않습니다. 각 페이지에 테두리를 표시하려면 페이지 나누기에서 수동으로 테두리를 설정해야 합니다.

그러나 길을 따라 행을 추가하거나 제거하면 페이지 나누기 줄과 테두리 줄이 떨어지기 때문에 다시 그리는 것이 번거로울 수 있습니다.

따라서 여기서는 매크로를 사용하여 페이지 나누기 줄에 테두리를 일괄적으로 그리는 방법을 사용하고자 합니다.

매크로를 병합하고 실행할 수 있으므로 모든 시작 메서드가 가능하지만 예제에서는 단추를 별도의 워크시트에 놓고 단추를 누를 때 페이지 나누기에 테두리를 그립니다.

매크로가 이미 포함된 파일을 배포하는 경우 파일을 전달하기만 하면 되지만 매크로를 직접 결합하려면 Excel을 설정하여 매크로를 결합합니다. 이 작업을 수행하는 방법에 대한 자세한 내용은 폼을 배치하거나 VBA 프로그래밍을 사용하도록 설정하는 개발 탭 보기를 참조하십시오.

단추를 배치하면 [매크로 등록] 대화 상자가 표시되므로 [새로 만들기] 단추를 눌러 클릭하여 클릭 이벤트를 수행합니다.

매크로 및 Visual Basic에는 자세히 설명이 없으므로 별도로 검토하십시오.

Visual Basic 편집기를 연 후 다음 코드를 추가합니다. 이 함수를 호출하면 지정된 워크시트의 페이지 나누기 줄에 테두리를 그릴 수 있습니다.

함수에 대한 설명은 주석을 참조하십시오.

'【概要】
'　改ページプレビューに合わせて、ページの下に黒の羅線を引きます。
'
'【引数】
'　targetSheet    : 改ページラインの描画対象シート
'  lineStyle      : 罫線のスタイル。XlLineStyle 列挙型から指定。
'  lineWeight     : 罫線の太さ。XlBorderWeight 列挙型から指定。
'  lineColorIndex : 罫線の色。XlColorIndex 列挙型から指定、またはカラー パレットのインデックス値を指定。
'
'【備考】
'  一度罫線を設定すると戻せないので注意。
Private Sub SetHPageBreakLines(targetSheet As Worksheet, _
                               Optional lineStyle As XlLineStyle = xlContinuous, _
                               Optional lineWeight As XlBorderWeight = xlThin, _
                               Optional lineColorIndex As XlColorIndex = xlAutomatic)

  ' 列の最大位置取得
  Dim maxColumn As Integer
  maxColumn = targetSheet.UsedRange.Columns.Count
    
  ' 各ページ描画
  For Each hpg In targetSheet.HPageBreaks
    Dim row As Integer
    Dim targetCell As Range
    row = hpg.Location.row - 1
    Set targetCell = targetSheet.Range(targetSheet.Cells(row, 1), targetSheet.Cells(row, maxColumn))
    
    ' 罫線のプロパティを設定する
    With targetCell.Borders(xlEdgeBottom)
      .lineStyle = lineStyle
      .Weight = lineWeight
      .ColorIndex = lineColorIndex
    End With
  Next
    
End Sub

단추를 클릭하는 절차는 다음과 같습니다. 만든 SetHPageBreakLines 함수에서 워크시트를 지정하여 워크시트에 테두리를 그립니다. 테두리 스타일을 지정하려면 나머지 매개변수를 사용하여 지정할 수 있습니다.

예제이므로 매크로에서 직접 시트 이름을 지정하지만 시트 이름을 설명하고 참조할 수 있는 셀을 만드는 것이 좋습니다.

'【概要】
'  ボタンクリックイベント
Sub ボタン1_Click()
  ' 対象シート
  Dim syoriSheet As Worksheet
  Set syoriSheet = Worksheets("ドキュメント")

  ' 罫線を設定
  Call SetHPageBreakLines(syoriSheet)

  ' 下は線のスタイル指定
  'Call SetHPageBreakLines(syoriSheet, xlContinuous, xlThin, xlAutomatic)

  MsgBox syoriSheet.HPageBreaks.Count & "ページ分の線の設定が完了しました。"
End Sub

매크로를 실행하면 각 페이지의 아래쪽 줄에 테두리가 설정되어 있다는 것을 알 수 있습니다. 인쇄 미리 보기에서 볼 수 있습니다.

매크로를 실행한 후에는 설정한 테두리를 반환할 수 없으므로 인쇄할 때만 매크로를 실행하고 인쇄하는 것이 좋습니다.