ایک میکرو میں صفحہ بہ صفحہ بنیاد پر صفحہ کے پایان پر بارڈر بنائیں

جائزہ

پرنٹ کرتے وقت ، مجھے لگتا ہے کہ یہ اکثر کاغذ کے فریم کے طور پر استعمال کیا جاتا ہے ہیڈر اور تمام چوکے پر سرحد کو ڈرا. تاہم ، اگر کاغذ ایک ہی شیٹ ہے ، تو آپ کو صرف دستی طور پر سرحد کو کھینچنے کی ضرورت ہے ، لیکن اگر یہ ایک سے زیادہ صفحہ بن جاتا ہے تو ، ہر صفحے کے نچلے حصے میں سرحد ظاہر نہیں ہوگا. دستی دوبارہ پل کی حمایت بھی ہے ، لیکن اگر آپ وسط میں لائنوں کو شامل یا ہٹا دیں تو ، آپ کو تمام صفحات پر سرحد کو دوبارہ ڈرا کرنا پڑے گا.

یہ سیکشن وضاحت کرتا ہے کہ کس طرح ہر صفحے کے نچلے حصے میں سرحدوں کو خود بخود اپنی طرف متوجہ کرنے کے لئے میکرو کا استعمال کریں.

عملیہ کی تصدیق شدہ ورژن

سپورٹ ایکسل ورژن

• 2010
• 2007
• 2003
• (یہ دوسرے ورژن کے ساتھ کام کر سکتے ہیں, لیکن اس بات کی تصدیق نہیں ہے.)

یقینی بنائیں ایکسل ورژن

• 2010
• 2007
• 2003

مشمولات

اگر آپ ایک صفحہ پرنٹ کرتے ہیں تو ، آپ کسی بھی مسائل کے بغیر پرنٹ کرنے کے لئے لائن کے نچلے حصے میں سرحد کو اپنی طرف متوجہ کرسکتے ہیں.

تاہم ، اگر آپ کے پاس ایک سے زیادہ صفحہ ہے تو ، آپ لائن کے نچلے حصے میں صرف ایک سرحد کو ڈرا سکتے ہیں ، لیکن سرحد ہر صفحے کی نیچے قطار پر ظاہر نہیں کرے گا. اگر آپ چاہتے ہیں کہ سرحد ہر صفحے پر ظاہر ہو تو آپ کو دستی طور پر صفحہ تبدیل کرنے کے لیے بارڈر کا اطلاق کرنا ہوگا ۔

تاہم ، اگر آپ وسط میں ایک لائن شامل یا خارج کرتے ہیں تو ، صفحہ وقفے کی لائن اور سرحد کی لائن کو کاٹ دیا جاتا ہے ، لہذا یہ مصیبت ہے کیونکہ یہ دوبارہ دوبارہ ڈرا بن جاتا ہے.

تو میں بلک میں صفحہ تبدیلی کی ایک لائن پر ایک سرحد کو اپنی طرف متوجہ کرنے کے لئے ایک میکرو استعمال کرنے جا رہا ہوں.

اس سے کوئی فرق نہیں پڑتا ہے کیونکہ آپ اسے بلٹ میں میکرو کے ساتھ چل سکتے ہیں ، لیکن نمونہ میں ، میں ایک علیحدہ شیٹ پر ایک بٹن رکھتا ہوں اور صفحہ وقفے پر ایک سرحد کو ڈراؤ جب میں بٹن دبائیں.

اگر آپ کسی ایسی چیز کو تقسیم کرنا چاہتے ہیں جو پہلے سے ہی میکرو پر مشتمل ہے ، تو آپ صرف فائل کو منتقل کرسکتے ہیں ، لیکن اگر آپ میکرو کو اپنے آپ کو جمع کرنا چاہتے ہیں تو ، ایکسل سیٹ کریں تاکہ آپ میکرو جمع کرسکیں. یہ کیسے کرنے کے بارے میں معلومات کے لئے ، دیکھیں فارم کی جگہ کا تعین اور VBA پروگرام کی ترقی کو فعال کرنے کے لئے ترقی ٹیب دکھائیں.

جب آپ ایک بٹن رکھیں تو ، میکرو رجسٹریشن ڈائیلاگ ظاہر ہوتا ہے ، لہذا آئیں اسے بنائیں تاکہ آپ "نیا" بٹن کو دبانے سے کلک کریں ایونٹ چلا سکیں.

ہم میکرو یا بصری بنیادی کے بارے میں بہت زیادہ تفصیل میں جانے کے لئے نہیں جا رہے ہیں ، تو اس کو علیحدہ طور پر چیک کریں.

جب بصری اساسی تدوین کار کھولتا ہے تو درج ذیل کوڈ شامل کریں: آپ اس فنکشن کو کال کرکے کسی مخصوص شیٹ پر صفحہ تبدیلیوں کی قطار پر سرحد کو اپنی طرف متوجہ کرسکتے ہیں.

میں تقریب کی وضاحت کے بارے میں ایک تبصرہ ہے ، لہذا براہ مہربانی اسے چیک کریں.

'【概要】
'　改ページプレビューに合わせて、ページの下に黒の羅線を引きます。
'
'【引数】
'　targetSheet    : 改ページラインの描画対象シート
'  lineStyle      : 罫線のスタイル。XlLineStyle 列挙型から指定。
'  lineWeight     : 罫線の太さ。XlBorderWeight 列挙型から指定。
'  lineColorIndex : 罫線の色。XlColorIndex 列挙型から指定、またはカラー パレットのインデックス値を指定。
'
'【備考】
'  一度罫線を設定すると戻せないので注意。
Private Sub SetHPageBreakLines(targetSheet As Worksheet, _
                               Optional lineStyle As XlLineStyle = xlContinuous, _
                               Optional lineWeight As XlBorderWeight = xlThin, _
                               Optional lineColorIndex As XlColorIndex = xlAutomatic)

  ' 列の最大位置取得
  Dim maxColumn As Integer
  maxColumn = targetSheet.UsedRange.Columns.Count
    
  ' 各ページ描画
  For Each hpg In targetSheet.HPageBreaks
    Dim row As Integer
    Dim targetCell As Range
    row = hpg.Location.row - 1
    Set targetCell = targetSheet.Range(targetSheet.Cells(row, 1), targetSheet.Cells(row, maxColumn))
    
    ' 罫線のプロパティを設定する
    With targetCell.Borders(xlEdgeBottom)
      .lineStyle = lineStyle
      .Weight = lineWeight
      .ColorIndex = lineColorIndex
    End With
  Next
    
End Sub

بٹن کے کلک کے عمل کو مندرجہ ذیل ہے. اگر آپ سیٹہپاگبریکلاناس فنکشن کے لئے ایک شیٹ کی وضاحت کرتے ہیں تو ، آپ اس شیٹ پر ایک سرحد اپنی طرف متوجہ کرسکتے ہیں. اگر آپ سرحدی طرز کی وضاحت بھی کرنا چاہتے ہیں تو ، آپ باقی دلائل کے ساتھ اس کی وضاحت کرسکتے ہیں.

کیونکہ یہ ایک نمونہ ہے ، شیٹ کا نام براہ راست میکرو میں بیان کیا جاتا ہے ، لیکن مجھے لگتا ہے کہ یہ ممکن ہے کہ سیل میں شیٹ کا نام لکھنا اور سیل کا حوالہ دینے کے قابل ہو.

'【概要】
'  ボタンクリックイベント
Sub ボタン1_Click()
  ' 対象シート
  Dim syoriSheet As Worksheet
  Set syoriSheet = Worksheets("ドキュメント")

  ' 罫線を設定
  Call SetHPageBreakLines(syoriSheet)

  ' 下は線のスタイル指定
  'Call SetHPageBreakLines(syoriSheet, xlContinuous, xlThin, xlAutomatic)

  MsgBox syoriSheet.HPageBreaks.Count & "ページ分の線の設定が完了しました。"
End Sub

جب آپ میکرو چلاتے ہیں ، تو آپ دیکھ سکتے ہیں کہ ہر صفحے کی سب سے نیچے قطار سرحد ہے. آپ اسے پرنٹ پیش نظارہ میں بھی دیکھ سکتے ہیں.

ایک لۓ کے طور پر ، مجھے لگتا ہے کہ جب میکرو کو پھانسی دی جاتی ہے تو یہ صرف پرنٹ کرنے کے لئے اچھا ہے کہ جب میکرو کو عملدرآمد کیا جاتا ہے تو واپس نہیں آسکتا ہے.